автор перевода: Koval Alexander	Предыдущая | Следующая | Оглавление

TextField.onScroller

Доступность

Flash Player 6.

Синтаксис

my_txt.onScroller = function(textFieldInstance:TextField){
  // Ваше выражение здесь
}
myListenerObj.onScroller = function(textFieldInstance:TextField){
  // Ваше выражение здесь

}

Параметры

textFieldInstance  Ссылка на объект текстовое поле

Возвращает

Ничего.

Описание

Обработчик событий; событие происходит при изменении свойств прокрутки в текстовом поле.

Ссылка на текстовое поле передается как параметр обработчику onScroller. Вы можете поймать эти данные помещением параметра в метод обработчика события. Для примера, следующий код использует my_txt как параметр который передается в обработчику события onScroller. Параметр использованый в выражении trace() передает имя экземпляра текстового поля в окно Output.

myTextField.onScroller = function (my_txt:TextField) {
  trace (my_txt._name + " scrolled");
};

Обработчик TextField.onScroller обычно используется для создания полос прокрутки. Полосы прокрутки обычно имеют бегунок или другой индикатор показывающий текущую горизонтальную или вертикальную позицию в текстовом поле. Текстовые поля могут управляться мышью или клавиатурой, которми указывается позиция прокрутки, для изменения. Програмный код полосы прокрутки нуждается что бы ему сообщили о изменении позиции прокрутки в следствии действий пользователя, вот для чего используется TextField.onScroller

onScroller вызывается если изменение положения полосы прокрутки вызвано действиями пользователя, или програмными изменениями. Обработчик onChanged действует только если пользователь сделал изменения. Эти две опции необходимы потому что часто часть кода изменяет позицию прокрутки, в то время как код полосы прокрутки с ним не связан и он не узнает что позиция прокрутки была изменена без уведомления.

Пример

Следующий пример создает текстовое поле названое my_txt, и использует две кнопки названные scrollUp_btn и scrollDown_btn соответственно, для прокрутки содержимого текстового поля. Когда обработчик события onScroller вызывается, выражение trace используется для вывода информации в окно Output. Создайте две кнопки с именами scrollUp_btn и scrollDown_btn соответственно, и добавьте следующий код в ваш FLA или AS файл:

this.createTextField("scroll_txt", this.getNextHighestDepth(), 10, 10, 160, 20);
this.createTextField("my_txt", this.getNextHighestDepth(), 10, 30, 320, 240);
my_txt.multiline = true;
my_txt.wordWrap = true;

for (var i = 0; i<10; i++) {
  my_txt.text += "Lorem ipsum dolor sit amet, consectetuer adipiscing elit, sed diam nonummy nibh euismod tincidunt ut laoreet dolore magna aliquam erat volutpat.";
}
scrollUp_btn.onRelease = function() {
  my_txt.scroll--;
};
scrollDown_btn.onRelease = function() {
  my_txt.scroll++;
};
my_txt.onScroller = function() {
  trace("onScroller called");
  scroll_txt.text = my_txt.scroll+" of "+my_txt.maxscroll;
};

См. также

TextField.hscroll, TextField.maxhscroll, TextField.maxscroll, TextField.scroll

Посмотреть коментарии LiveDocs		Предыдущая| Следующая | Оглавление